Часы на ESP8266 и TM1637 с синхронизацией с NTP сервером через интернет

По немногочисленным просьбам, не большей проект на ESP8266, Часы с синхронизацией с сервером точного времени и выводом на модуль 7 сегментного индикатора TM1637

ниже код из видео



Как все подключено:

ESP8266_M1637Если использовать NodeMCU

 

Железки на али:

7-segments TM1637
NodeMcu Lua Development Board
ESP8266 ESP-01

Код:

под спойлером
/* Udp NTP Client Get the time from a Network Time Protocol (NTP) time server Demonstrates use of UDP sendPacket and ReceivePacket For more on NTP time servers and the messages needed to communicate with them, see http://en.wikipedia.org/wiki/Network_Time_Protocol created 4 Sep 2010 by Michael Margolis modified 9 Apr 2012 by Tom Igoe updated for the ESP8266 12 Apr 2015  by Ivan Grokhotkov This code is in the public domain. */

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
#include "TM1637.h"
#include <Ticker.h>

Ticker flipper;
TM1637 tm1637(12, 14);              // CLK, DIO (D6, D5)

#define GMT 3                       // часовой пояс
#define brightness 4               // яркость, от 0 до 7

char ssid[] = "WLAN1";             //  your network SSID (name)
char pass[] = "1231234123";        // your network password

byte hour, minute, second;
boolean point;

unsigned int localPort = 2390;      // local port to listen for UDP packets

/* Don't hardwire the IP address or we won't get the benefits of the pool. *  Lookup the IP address for the host name instead */
//IPAddress timeServer(129, 6, 15, 28); // time.nist.gov NTP server
IPAddress timeServerIP; // time.nist.gov NTP server address
const char* ntpServerName = "time.nist.gov";

const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
WiFiUDP udp;

void setup()
{
  Serial.begin(115200); 
   
  tm1637.init();                      ///tm1637
  tm1637.set(brightness);

  flipper.attach(1, flip);          /// прерывание 1 сек
  
  Serial.println();
  Serial.println();

  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  Serial.println("Starting UDP");
  udp.begin(localPort);
  Serial.print("Local port: ");
  Serial.println(udp.localPort());

  oldloop();        /// синхронизируем время при включении 
}

void loop(){
  if (second == 30){            // если насчитали 30 сек
    flipper.detach();           // выключаем прерывание
    delay(1500);                // ждем, чтобы повторно не запустить
    oldloop();                  // синхронизируем время
    flipper.attach(1, flip);    // запускаем прерывание
  }
  
   int8_t TimeDisp[4];          // отправляем всё на экран 
   tm1637.point(point);         // управление :, мигаем если запущено прерывание
   
   TimeDisp[0] = hour / 10;
   TimeDisp[1] = hour % 10;
   TimeDisp[2] = minute  / 10;
   TimeDisp[3] = minute  % 10;  
   tm1637.display(TimeDisp);
}

void oldloop()
{
  //get a random server from the pool
  WiFi.hostByName(ntpServerName, timeServerIP); 

  sendNTPpacket(timeServerIP); // send an NTP packet to a time server
  // wait to see if a reply is available
  delay(1000);
  
  int cb = udp.parsePacket();
  if (!cb) {
    Serial.println("no packet yet");
  }
  else {
    Serial.print("packet received, length=");
    Serial.println(cb);
    // We've received a packet, read the data from it
    udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears;
    // print Unix time:
    Serial.println(epoch);
    
          /// корректировка часового пояса и синхронизация 
    epoch = epoch + GMT * 3600;     
    
    hour = (epoch  % 86400L) / 3600;
    minute = (epoch  % 3600) / 60;
    second = epoch % 60;
   

    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':');
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch % 60); // print the second
  }
  // wait ten seconds before asking for the time again

 
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  Serial.println("sending NTP packet...");
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  udp.beginPacket(address, 123); //NTP requests are to port 123
  udp.write(packetBuffer, NTP_PACKET_SIZE);
  udp.endPacket();
}


void flip(){ 
  point = !point;
  second++; 
  if (second > 59){
    second = 0;
    minute++;      
  }
  if (minute > 59){
    minute = 0;
    hour++;  
  }
  if (hour > 23){
    hour = 0;
  } 

} 


Итог:

IMG_6675 IMG_6678 IMG_6681

На плате стабилизатор питания на AMS117-3.3, пара кондеров и немного проводов, ESP8266 ESP-01 установленна в колодку чтобы оставить возможность перепрошивки, и соответственно в коде, в строке «TM1637 tm1637(12, 14);» указаны выходы для CLK, DIO на 0 и 2 GPIO.


Версия 2.0

Код обновленной версии с часами реального времени, подробнее в видео.

Тут
 
#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
#include "TM1637.h"
#include <Ticker.h>
#include <Wire.h>
#include <Rtc_Pcf8563.h>                                      // https://codeload.github.com/elpaso/Rtc_Pcf8563/zip/master

#define GMT 3                       // часовой пояс
#define brightness 4                // яркость, от 0 до 7
#define CLK 1                      // (12 - D6, 14 - D5)
#define DIO 3
#define SDA 0
#define SCL 2

Ticker flipper;
TM1637 tm1637(CLK, DIO);              
Rtc_Pcf8563 rtc;


char ssid[] = "WLAN1";             //  your network SSID (name)
char pass[] = "1231234123";        // your network password

byte hour, minute, second;
boolean point;

unsigned int localPort = 2390;      // local port to listen for UDP packets

 
IPAddress timeServerIP;                                     // time.nist.gov NTP server address
//const char* ntpServerName = "time.nist.gov";
const char* ntpServerName = "ntp4.stratum2.ru";

const int NTP_PACKET_SIZE = 48;                             // NTP time stamp is in the first 48 bytes of the message
byte packetBuffer[ NTP_PACKET_SIZE];                        //buffer to hold incoming and outgoing packets
 
WiFiUDP udp;                                                // A UDP instance to let us send and receive packets over UDP

void setup()
{
//    Serial.begin(115200); 
  delay(1000);
  Wire.begin(SDA, SCL);
 // rtc.initClock();                                     //clear out the registers

  tm1637.init();                                         ///tm1637
  tm1637.set(brightness);

  flipper.attach(1, flip);                              /// прерывание 1 сек
  
  
   wificonnect();                                   // синхронизируем время при включении
   sync(); 
//   
 
  
}

void loop(){ 
   int8_t TimeDisp[4];          
   tm1637.point(point);                                 // управление :, мигаем если запущено прерывание
                               
   rtc.getDateTime();
    hour = rtc.getHour();
   TimeDisp[0] = hour / 10;
   TimeDisp[1] = hour % 10;
    minute = rtc.getMinute();
   TimeDisp[2] = minute  / 10;
   TimeDisp[3] = minute  % 10;  
   tm1637.display(TimeDisp);                            // отправляем всё на экран   
    second = rtc.getSecond();
    
   if (minute == 0 && second == 10){                    // синхронизируем время в начале каждого часа
     wificonnect(); 
     sync(); 
   }

}

// We start by connecting to a WiFi network
void wificonnect(){ 
//  Serial.print("Connecting to ");
//  Serial.println(ssid);
  WiFi.begin(ssid, pass);

  int i = 0;
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    i++;
    if (i > 40) break;
 //   Serial.print(i);
  }
//  Serial.println("");
  
//  Serial.println("WiFi connected");
//  Serial.println("IP address: ");
//  Serial.println(WiFi.localIP());
//
//  Serial.println("Starting UDP");
  udp.begin(localPort);
//  Serial.print("Local port: ");
//  Serial.println(udp.localPort());  
}


void sync(){ 
  //get a random server from the pool
  WiFi.hostByName(ntpServerName, timeServerIP); 

  sendNTPpacket(timeServerIP); // send an NTP packet to a time server
  // wait to see if a reply is available
  delay(1000);
  
  int cb = udp.parsePacket();
  if (!cb) {
    // если пакет не получили, продолжаем работать 
//    Serial.println("no packet yet");     
    // а можно продолжать пинать сервер в рекурсии
//    sync(); 

  }
  else {
//    Serial.print("packet received, length=");
//    Serial.println(cb);
    // We've received a packet, read the data from it
    udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
//    Serial.print("Seconds since Jan 1 1900 = " );
//    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
//    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears;
    // print Unix time:
//    Serial.println(epoch);
    
          /// корректировка часового пояса и синхронизация 
    epoch = epoch + GMT * 3600;     
    
    hour = (epoch  % 86400L) / 3600;
    minute = (epoch  % 3600) / 60;
    second = epoch % 60;
     
    rtc.setTime(hour , minute, second);
   
  }
  // wait ten seconds before asking for the time again
 WiFi.disconnect();                                                           // отключаемся от сети
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
//  Serial.println("sending NTP packet...");
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  udp.beginPacket(address, 123); //NTP requests are to port 123
  udp.write(packetBuffer, NTP_PACKET_SIZE);
  udp.endPacket();
}


void flip(){ 
  point = !point;
  

}